# Programming/Kdb/Labs/Option pricing

< Programming‎ | Kdb‎ | Labs
(diff) ← Older revision | Latest revision (diff) | Newer revision → (diff)

# Background: the Black-Scholes formulae

Recall the celebrated Black-Scholes equation

${\displaystyle {\frac {\partial V}{\partial t}}+{\frac {1}{2}}\sigma ^{2}S^{2}{\frac {\partial ^{2}V}{\partial S^{2}}}+(r-q)S{\frac {\partial V}{\partial S}}-rV=0.}$

Here

• ${\displaystyle t}$ is a time in years; we generally use ${\displaystyle t=0}$ as now;
• ${\displaystyle V(S,t)}$ is the value of the option;
• ${\displaystyle S(t)}$ is the price of the underlying asset at time ${\displaystyle t}$;
• ${\displaystyle \sigma }$ is the volatility — the standard deviation of the asset's returns;
• ${\displaystyle r}$ is the annualized risk-free interest rate, continuously compounded;
• ${\displaystyle q}$ is the annualized (continuous) dividend yield.

The solution of this equation depends on the payoff of the option — the terminal condition. In particular, if at the time of expiration, ${\displaystyle T}$, the payoff is given by ${\displaystyle V(S,T)=C(S,T)=:\max\{S-K,0\}}$, in other words, the option is a European call option, then the value of the option at time ${\displaystyle t}$ is given by the Black-Scholes formula for the European call:

${\displaystyle C(S_{t},t)=e^{-r\tau }[F_{t}N(d_{1})-KN(d_{2})]}$

where ${\displaystyle \tau =T-t}$ is the time to maturity, ${\displaystyle F=S_{t}e^{(r-q)\tau }}$ is the forward price, and

${\displaystyle d_{1}={\frac {1}{\sigma {\sqrt {\tau }}}}\left[\ln \left({\frac {S_{t}}{K}}\right)+\left(r-q+{\frac {1}{2}}\sigma ^{2}\right)\tau \right]}$

and

${\displaystyle d_{2}=d_{1}-\sigma {\sqrt {\tau }}.}$

Here we have used ${\displaystyle N(x)}$ to denote the standard normal cumulative distribution function,

${\displaystyle N(x)={\frac {1}{\sqrt {2\pi }}}\int _{-\infty }^{x}e^{-z^{2}/2}\,dz.}$

Similarly, if the payoff is given by ${\displaystyle V(S,T)=P(S,T)=:\max\{K-S,0\}}$, in other words, the option is a European put option, then the value of the option at time ${\displaystyle t}$ is given by the Black-Scholes formula for the European put:

${\displaystyle P(S_{t},t)=e^{-r\tau }[KN(-d_{2})-F_{t}N(-d_{1})].}$

We will implement the formulae for the European call and European put in q. However, our first task is to implement ${\displaystyle N(x)}$.

# Task 1: Implementing the standard normal cumulative distribution function

As mentioned in the Handbook of Mathematical Functions, ${\displaystyle N(x)}$ can be approximated by

${\displaystyle \left\{{\begin{array}{ll}1-\phi (x)\left[c_{1}k+c_{2}k^{2}+c_{3}k^{3}+c_{4}k^{4}+c_{5}k^{5}\right],&x\geq 0,\\1-N(-x),&x<0,\end{array}}\right.}$

where

${\displaystyle \phi (x)=\exp(-x^{2}/2)/{\sqrt {2\pi }},}$

${\displaystyle k=1/(1+0.2316419x),c_{1}=0.319381530,c_{2}=-0.356563782,c_{3}=1.781477937,c_{4}=-1.821255978,c_{5}=1.330274429.}$

Can you implement this function in q?

First, we need

pi:acos -1;


One (terse) implementation would be

normal_cdf:{abs(x>0)-(exp[-.5*x*x]%sqrt 2*pi)*t*.31938153+t*-.356563782+t*1.781477937+t*-1.821255978+1.330274429*t:1%1+.2316419*abs x};


# Task 2: Implement the Black-Scholes formula for the European call and put

Equipped with our implementation of normal_cdf, can you implement the Black-Scholes formula for the European call?

First, we need

compute_d1:{[S;K;r;q;sigma;tau](log[S%K]+((r-q)+.5*sigma*sigma)*tau)%sigma*sqrt tau};


Then,

call_price:{[S;K;r;q;sigma;tau]
d1:compute_d1[S;K;r;q;sigma;tau];
d2:d1-sigma*sqrt tau;
F:S*exp tau*r-q;
(exp neg r*tau)*(F*normal_cdf d1)-K*normal_cdf d2};


and

put_price:{[S;K;r;q;sigma;tau]
d1:compute_d1[S;K;r;q;sigma;tau];
d2:d1-sigma*sqrt tau;
F:S*exp tau*r-q;
(exp neg r*tau)*(K*normal_cdf neg d2)-F*normal_cdf neg d1};


We can test these implementations on a few sets of parameters, for example

call_price[100f;105f;.05;.07;.1;.5]


gives 0.7991363, whereas

put_price[100f;105f;.05;.07;.1;.5]


gives 6.646135.

# Background: a simple Monte Carlo model

The Black-Scholes equation may not have analytic solutions for all derivatives that we are interested in. However, it may still be possible to solve it numerically using Monte Carlo methods.

The model for stock price evolution is

${\displaystyle dS_{t}=\mu S_{t}\,dt+\sigma S_{t}\,dW_{t},}$

where ${\displaystyle \mu }$ is the drift. The Black-Scholes pricing theory then tells us that the price of a vanilla option with pay-off ${\displaystyle f}$ is equal to

${\displaystyle e^{-r\tau }\mathbb {E} [f(S_{T})],}$

where the expectation is taken under the associated risk-neutral process,

${\displaystyle dS_{t}=(r-q)S_{t}\,dt+\sigma S_{t}\,dW_{t}.}$

We solve this equation by passing to the log and using Ito's lemma; we compute

${\displaystyle d\ln S_{t}=\left(r-q-{\frac {1}{2}}\sigma ^{2}\right)\,dt+\sigma \,dW_{t}.}$

As this process is constant-coefficient, it has the solution

${\displaystyle \ln S_{t}=\ln S_{0}+\left(r-q-{\frac {q}{2}}\sigma ^{2}\right)t+\sigma W_{t}.}$

Since ${\displaystyle W_{t}}$ is a Brownian motion, ${\displaystyle W_{T}}$ is distributed as a Gaussian with mean zero and variance ${\displaystyle T}$, so we can write

${\displaystyle W_{T}={\sqrt {T}}N(0,1),}$

and hence

${\displaystyle \ln S_{T}=\ln S_{0}+\left(r-q-{\frac {q}{2}}\sigma ^{2}\right)T+\sigma {\sqrt {T}}N(0,1),}$

or equivalently,

${\displaystyle S_{T}=S_{0}\exp \left[\left(r-q-{\frac {q}{2}}\sigma ^{2}\right)T+\sigma {\sqrt {T}}N(0,1)\right].}$

The price of a vanilla option is therefore equal to

${\displaystyle e^{-rT}\mathbb {E} \left[f\left(S_{0}\exp \left[\left(r-q-{\frac {q}{2}}\sigma ^{2}\right)T+\sigma {\sqrt {T}}N(0,1)\right]\right)\right].}$

The objective of our Monte Carlo simulation is to approximate this expectation by using the law of large numbers, which tells us that if ${\displaystyle Y_{j}}$ are a sequence of identically distributed independent random variables, then with probability 1 the sequence

${\displaystyle {\frac {1}{N}}\sum _{j=1}^{N}Y_{j}}$

converges to ${\displaystyle \mathbb {E} [Y_{1}]}$.

So the algorithm to price a call option by Monte Carlo is clear. We draw a random variable, ${\displaystyle x}$, from an ${\displaystyle N(0,1)}$ distribution and compute

${\displaystyle f\left(S_{0}\exp \left[\left(r-q-{\frac {q}{2}}\sigma ^{2}\right)T+\sigma {\sqrt {T}}N(0,1)\right]\right).}$

We do this many times and take the average. We then multiply this average by ${\displaystyle e^{-rT}}$ and we are done.

# Task 3: Generating standard Gaussian random variates

To generate 10 standard uniform random variates in q, we can simply use

10?1f


How can we convert these standard uniform random variates into standard Gaussian random variates?

One approach is to use the Box-Muller transform. Suppose ${\displaystyle U_{1}}$ and ${\displaystyle U_{2}}$ are independent samples chosen from the uniform distribution on the unit interval ${\displaystyle [0,1]}$. Let

${\displaystyle Z_{0}={\sqrt {-2\ln U_{1}}}\cos(2\pi U_{2})}$

and

${\displaystyle Z_{1}={\sqrt {-2\ln U_{1}}}\sin(2\pi U_{2}).}$

Then ${\displaystyle Z_{0}}$ and ${\displaystyle Z_{1}}$ are independent random variables with a standard normal distribution.

Equipped with Box-Muller transform, implement a function in q that, given a number ${\displaystyle x}$, will return ${\displaystyle x}$ standard Gaussian random variates.

normal_variates:{\$[x=2*n:x div 2;raze sqrt[-2*log n?1f]*/:(sin;cos)@\:(2*pi)*n?1f;-1_.z.s 1+x]}


# Task 4: Implement a Monte Carlo pricer

We are now ready to implement a Monte Carlo pricer. We can use it to price more complicated options than the European call and put. However, the European call and put are convenient — the analytic solutions enable us to test our Monte Carlo pricer.

mc:{[S;r;q;sigma;T;path_count;payoff]
root_variance:sqrt variance:sigma*sigma*T;
moved_spot:S*exp (ito_correction:-.5*variance)+(r-q)*T;
exp[neg T*r]*avg payoff moved_spot*exp[root_variance*normal_variates path_count]};


Let's define the European call and put payoffs:

call_payoff:{[K;S]0|S-K}
put_payoff:{[K;S]0|K-S}


We can now test our Monte Carlo pricer on these payoffs and confirm that we get similar answers to those produced by the analytic formulae:

mc[100f;.05;.07;.1;.5;100000;call_payoff[105f]]
mc[100f;.05;.07;.1;.5;100000;put_payoff[105f]]


# Task 5: Pricing a double digital option

We shall now use our q Monte Carlo pricer to price a double digital option.

First, we implement the double digital payoff:

double_digital_payoff:{[L;U;S]?[(S<L)|S>U;z;1f+z:0f*S]}


We are now ready to price a double digital option:

mc[100f;.05;.07;.1;.5;100000;double_digital_payoff[105f;110f]]


The result will vary (due to the Monte Carlo randomness), but it will be around 0.1260532.